Zobrazení zdroje stránky Vimscript

{{Infobox - programovací jazyk
| název = Vimscript
| paradigma = [[imperativní programování|imperativní]]
| autor = [[Bram Moolenaar]]
| typování = dynamická
| implementace = [[Vim]]
| ovlivněno = [[C (programovací jazyk)|C]] <!-- další? -->
| operační systém = [[Unix|UNIX]], [[GNU]]/[[Linux]], [[Windows NT]], [[macOS]], [[iOS]], [[AmigaOS]], [[MorphOS]]
| licence = [[GNU General Public License|GPL]]-kompatibilní [[charityware]]
| web = [https://www.vim.org/scripts/index.php vim.org]
}}
'''Vimscript''' (nebo '''Vim script''') je [[Typová kontrola|dynamicky typovaný]] [[imperativní programování|imperativní]] [[skriptovací jazyk]] textového editoru [[Vim]]. Vychází z příkazového jazyka editoru [[ex (textový editor)|ex]].

Uživatel pomocí Vimscriptu může do editoru nadefinovat nové schopnosti, zefektivnit často prováděné úlohy, pozměnit chování standardních schopností editoru či je zcela nahradit svými algoritmy. Pluginy a makra Vimu jsou psána ve Vimscriptu. Podobá se ostatním skriptovacím jazykům jako je například [[Perl]]. Vimscript může být zapisován přímo v prostředí Vimu ve formě příkazů nebo (běžnější) uložen v obyčejném [[Textový soubor|textovém souboru]] s koncovkou ''.vim''.

== Ukázka Vimscriptu ==

<syntaxhighlight lang="text">
function Minimum ( cislo1, cislo2 )
  if a:cislo1 < a:cislo2
    let mensi = a:cislo1
  else
    let mensi = a:cislo2
  endif
  return mensi
endfunction
</syntaxhighlight>

Tento kód napsaný ve Vimscriptu definuje novou funkci se jménem "Minimum", která bere dva argumenty (cislo1 a cislo2). Funkce obsahuje jednu podmínku, dvě přiřazení a jeden návratový příkaz.

== Vlastnosti Vimscriptu ==

* Příkazy
* Proměnné
* Výrazy
* [[Regulární výraz]]y
* Řídící konstrukty
** Podmínka
** Cyklus
* Funkce
* Seznamy a slovníky
* Výjimky

=== Příkazy ===

Poznámka: jedná se o příkazy použitelné v [[Vim#Režimy editoru Vim|režimu ex]]; při interaktivním zadávání v [[Vim#Režimy editoru Vim|základním]] režimu je nutné před příkazy napsat dvojtečku.

Přiřazovací příkaz:

* <code>let proměnná = výraz</code>

Výpis hodnoty do stavového řádku:

* <code>echo výraz</code>

– lze použít pro zkoušení, jak fungují funkce – například <code>echo line('.')</code> vypíše do stavového řádku číslo aktuálního řádku

Volání procedury:

* <code>call jméno(parametry)</code>

Provedení příkazu v normálním ([[Vim#Režimy editoru Vim|základním]], příkazovém) režimu:

* <code>normal příkaz</code>

– například <code>normal 4dd</code> smaže řádek, na kterém stojí kurzor, a další 3 řádky

Provedení dvojtečkového příkazu:

* <code>execute příkaz</code>

– příkaz <code>execute line('.') "," line('.')+3 "d"</code> také smaže řádek, na kterém stojí kurzor, a další 3 řádky (tento příkaz je pouze pro ilustraci, místo <code>line('.')</code> a <code>line('.')+3</code> lze použít libovolné výrazy, pro tento speciální případ by samozřejmě bylo jednodušší použít <code>execute ".,+3d"</code>)

=== Proměnné ===

Lokální proměnné jsou identifikátory bez prefixu, parametry mají prefix <code>a:</code>, globální proměnné prefix <code>g:</code>.

=== Funkce ===

* <code>line('.')</code> – vrací číslo řádku, na kterém stojí kursor (1 = první řádek)
* <code>line('$')</code> – vrací číslo posledního řádku řádku v aktuálním bufferu
* <code>col('.')</code> – vrací číslo bytu na pozici kursoru od začátku řádku (1 = kursor je začátku řádku)
* <code>col('$')</code> – vrací číslo bytu za posledním znakem řádku, na kterém stojí kursor
* <code>virtcol('.')</code> – vrací číslo pozice, které stojí kursor
* <code>getline('.')</code> – vrací obsah řádku, na kterém stojí kursor
* <code>call setline('.', řetězec)</code> – změní obsah řádku, na kterém stojí kursor na zadaný řetězec
* <code>call cursor(řádek, pozice)</code> – nastaví kursor na zadaný řádek a pozici na řádku (obojí číslované od 1)
* <code>strpart(řetězec, začátek, délka)</code> – vrací podřetězec z řetězce zadaného prvním parametrem začínající na pozici zadané druhým parametrem (číslované od 0), o délce zadané třetím parametrem; není-li uveden třetí parametr, bere se podřetězec do konce původního řetězce
* <code>search(regexp[, flagy[, stopline[, timeout]]])</code> – hledá od aktuální pozice kursoru řetězec vyhovující [[Regulární výraz|regulárnímu výrazu]] regexp, flagy ovlivňují způsob hledání (pro další informace použijte ve vimu příkaz :help search); při úspěchu přesune kursor a vrátí číslo řádku; při neúspěchu kursor ponechá na původním místě a vrátí 0
* <code>input(výzva)</code> – vypíše výzvu do stavového řádku, čeká na zadání řetězce, který vrátí jako návratovou hodnotu

== Příklad ==

Následující příklad definuje příkazy <code>cp</code> a <code>cP</code>, které se chovají podobně jako standardní příkazy <code>p</code> a <code>P</code> – tj. vloží za kursor, resp. před kursor text z pomocné bufferu; na rozdíl od nich však vkládaný text oddělí od původního textu vložením mezery na začátku a/nebo na konci jako by se jednalo o jedno nebo více samostatných slov.

<syntaxhighlight lang="text">
set nocompatible

function! WholeWordPut(put_before)
    if a:put_before == 0
" vložení za kursor
" pozice znaku, za který se vkládá
        let lpos = col('.')-1
" příkaz l posune kursor o pozici doprava
        execute "normal" "l"
" pozice znaku, před který se vkládá
        let rpos = col('.')-1
        execute "normal" "l"
" pozice dalšího znaku
        let xpos = col('.')-1
        if xpos == rpos
            let xpos = col('$')-1
        else
            execute "normal" "h"
        endif
        if rpos == lpos
            let rpos = col('$')-1
        else
            execute "normal" "h"
        endif
    else
" vložení před kursor
        let rpos = col('.')-1
        execute "normal" "h"
        let lpos = col('.')-1
        if rpos != lpos
            execute "normal" "l"
        endif
        execute "normal" "l"
        let xpos = col('.')-1
        if xpos == rpos
            let xpos = col('$')-1
        else
            execute "normal" "h"
        endif
    endif
" znak, za který se vkládá
    let lchar = strpart(getline('.'), lpos, rpos-lpos)
" znak, před který se vkládá
    let rchar = strpart(getline('.'), rpos, xpos-rpos)
    if lchar == '' || match(lchar, '[(\[{< ]') == 0
" na začátku řádku a za otevírací závorku nevkládat před vložený text mezeru
        let put_string = substitute(@@, '^ *', '', '')
    else
        let put_string = substitute(@@, '^ *', ' ', '')
    endif
    if rchar == '' || match(rchar, '[)\]}> \.,?!:;]') == 0
" na konci řádku, před zavírací závorku a interpunkci nevkládat za vložený text mezeru
        let put_string = substitute(put_string, ' *$', '', '')
    else
        let put_string = substitute(put_string, ' *$', ' ', '')
    endif
" Vložení textu
    call setline('.', strpart(getline('.'), 0, rpos) . put_string . strpart(getline('.'), rpos))
" Umístění kursoru
    call cursor(line('.'), rpos+strlen(put_string))
endfunction

noremap cp :call WholeWordPut(0)<CR>
noremap cP :call WholeWordPut(1)<CR>
</syntaxhighlight>

== Externí odkazy ==

* [http://vimdoc.sourceforge.net/htmldoc/usr_41.html Část dokumentace editoru Vim popisující Vimscript]
* [http://www.vim.org/scripts/index.php Databáze programů ve Vimscriptu]
* [http://vim.wikia.com/wiki/Vim_scripts Příklady ve Vimscriptu]

{{Programovací jazyky}}

[[Kategorie:Programovací jazyky]]