BeschreibungParitition of dynamic plane of quadratic polynomial for 129 over 16256.svg	English: Partition of dynamic plane of complex quadratic polynomial ${\displaystyle f_{t}(z)=f_{c}(z)=z^{2}+c_{t}}$ for t = 129 /16256. Julia set is a dendrite ( = connected with no interior). Parameter ${\displaystyle c=c(t)=0.133511204871878+0.397391822296541i}$ is a Misiurewicz point. External dynamic ray for angle t lands on the critical value z= c ( image of the critical point z = 0 ). Two external rays for the angles t/2 and (t+1)/2 land on the critical point. These rays and their landing point ( critical point z = 0) divide the dynamic plane into two components. This partition used in the definition of the kneading sequence[1] of the external angle t[2]
Datum	13. August 2019
Quelle	Eigenes Werk
Urheber	Adam Majewski
Andere Versionen

Ich, der Urheber dieses Werkes, veröffentliche es unter der folgenden Lizenz:

Diese Datei ist lizenziert unter der Creative-Commons-Lizenz „Namensnennung – Weitergabe unter gleichen Bedingungen 4.0 international“.

Dieses Werk darf von dir

• verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden
• neu zusammengestellt werden – abgewandelt und bearbeitet werden

Zu den folgenden Bedingungen:

• Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders.
• Weitergabe unter gleichen Bedingungen – Wenn du das Material wiedermischst, transformierst oder darauf aufbaust, musst du deine Beiträge unter der gleichen oder einer kompatiblen Lizenz wie das Original verbreiten.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue

 /*  
batch file for Maxima CAS

maxima
batch("k.mac");

------------ program Mandel by Wolf Jung -------------------------
The angle  3/30  or  0p0011
has  preperiod = 1  and  period = 4.
The corresponding parameter ray is landing
at a Misiurewicz point of preperiod 1 and
period dividing 4.
Do you want to draw the ray and to shift c
to the landing point?
-------------------



 */ 



kill(all);
remvalue(all);
ratprint:false; /*  It doesn't change the computing, just the warnings. */
display2d:false;





 /* --------------------------definitions of functions ------------------------------*/
 f(z,c):=z*z+c; /* Complex quadratic map */
 finverseplus(z,c):=float(rectform(sqrt(z-c)))$
 finverseminus(z,c):=float(rectform(-sqrt(z-c)))$ 

/* */
fn(p, z, c) :=
  if p=0 then z
  elseif p=1 then f(z,c)
  else f(fn(p-1, z, c),c)$

/*Standard polynomial F_p \, which roots are periodic z-points of period p and its divisors */
F(p, z, c) := fn(p, z, c) - z $

/* Function for computing reduced polynomial G_p\, which roots are periodic z-points of period p without its divisors*/
G[p,z,c]:=
block(
[f:divisors(p),
t:1], /* t is temporary variable = product of Gn for (divisors of p) other than p */
f:delete(p,f), /* delete p from list of divisors */
if p=1
then return(F(p,z,c)),
for i in f do 
 t:t*G[i,z,c],
g: F(p,z,c)/t,
return(ratsimp(g))
)$

GiveRoots(g):=
 block(
 [cc],
 cc:bfallroots(expand(%i*g)=0),
 cc:map(rhs,cc),/* remove string "c=" */
 cc:map('float,cc),
 return(cc)
  )$ 






 /* Gives points of backward orbit of z=repellor  
 
   problem for 1/10 
      */
 GiveBackwardOrbit(c,repellor,zxMin,zxMax,zyMin,zyMax,iXmax,iYmax,  hit_limit):=
  block(
   hit_limit:10, /* proportional to number of details and time of drawing */
   PixelWidth:(zxMax-zxMin)/iXmax,
   PixelHeight:(zyMax-zyMin)/iYmax,
   /* 2D array of hits pixels . Hit > 0 means that point was in orbit */
   array(Hits,fixnum,iXmax,iYmax), /* no hits for beginning */
  /* choose repeller z=repellor as a starting point */
  stack:[repellor], /*save repellor in stack */
  /* save first point to list of pixels  */ 
  x_y:[repellor], 
 /* reversed iteration of repellor */
  loop,
  /* pop = take one point from the stack */
  z:last(stack),
  stack:delete(z,stack),
  /*inverse iteration - first preimage (root) */
  z:finverseplus(z,c),
  /* translate from world to screen coordinate */
  iX:fix((realpart(z)-zxMin)/PixelWidth),
  iY:fix((imagpart(z)-zyMin)/PixelHeight),
  hit:Hits[iX,iY],
  if hit<hit_limit   
   then 
    (
    Hits[iX,iY]:hit+1,
    stack:endcons(z,stack), /* push = add z at the end of list stack */
    if hit=0 then x_y:endcons( z,x_y)
    ),
  /*inverse iteration - second preimage (root) */
  z:-z,
 /* translate from world to screen coordinate, coversion to integer */
  iX:fix((realpart(z)-zxMin)/PixelWidth),
  iY:fix((imagpart(z)-zyMin)/PixelHeight),
  hit:Hits[iX,iY],
  if hit<hit_limit   
   then 
    (
     Hits[iX,iY]:hit+1,
     stack:endcons(z,stack), /* push = add z at the end of list stack to continue iteration */
     if hit=0 then x_y:endcons( z,x_y)
    ),
   if is(not emptyp(stack)) then go(loop), 
 return(x_y) /* list of pixels in the form [z1,z2] */
 )$

 
 
 /*-----------------------------------*/ 
 Psi_n(r,t,z_last, Max_R):=
 /*   */
 block(
  [iMax:200,
  iMax2:0],
  /* -----  forward iteration of 2 points : z_last and w --------------*/
  array(forward,iMax-1), /* forward orbit of z_last for comparison */
  forward[0]:z_last,
  i:0,
  while cabs(forward[i])<Max_R  and  i< ( iMax-2) do
  (     
  /* forward iteration of z in fc plane & save it to forward array */
  forward[i+1]:forward[i]*forward[i] + c, /* z*z+c */
  /* forward iteration of w in f0 plane :  w(n+1):=wn^2 */
  r:r*2, /* square radius = R^2=2^(2*r) because R=2^r */
  t:mod(2*t,1),
  /* */
  iMax2:iMax2+1,
  i:i+1
  ),
  /* compute last w point ; it is equal to z-point */
  R:2^r,
  /* w:R*exp(2*%pi*%i*t),       z:w, */
  array(backward,iMax-1),
  backward[iMax2]:float(rectform(ev(R*exp(2*%pi*%i*t)))), /* use last w as a starting point for backward iteration to new z */
  /* -----  backward iteration point  z=w in fc plane --------------*/
  for i:iMax2 step -1 thru 1 do
  (
  temp:float(rectform(sqrt(backward[i]-c))), /* sqrt(z-c) */
  scalar_product:realpart(temp)*realpart(forward[i-1])+imagpart(temp)*imagpart(forward[i-1]),
  if (0>scalar_product) then temp:-temp, /* choose preimage */
  backward[i-1]:temp
  ),
  return(backward[0])
 )$
 
 
 
 
 
 /* problems for c= -2 and t = 1/2 */
 GiveRay(t,c):=
 block(
  [r],
  /* range for drawing  R=2^r ; as r tends to 0 R tends to 1 */
  rMin:1E-10, /* 1E-4;  rMin > 0  ; if rMin=0 then program has infinity loop !!!!! */
  rMax:3, 
  dz : 100, /*  dz : cabs ( z - last_z)  ; if dz is to small then loop is not ending   */
  MachineEpsilonDouble: 1E-16,
  
  caution:0.9330329915368074, /* r:r*caution ; it gives smaller r */
  /* upper limit for iteration */
  R_max:300,
  /* */
  zz:[], /* array for z points of ray in fc plane */
  /*  some w-points of external ray in f0 plane  */
  r:rMax,
  while 2^r<R_max do r:2*r, /* find point w on ray near infinity (R>=R_max) in f0 plane */
  R:2^r,
  w:float(rectform(ev(R*exp(2*%pi*%i*t)))),
  z:w, /* near infinity z=w */
  zz:cons(z,zz),
  unless (r<rMin  or dz < MachineEpsilonDouble) do
  (     /* new smaller R */
  	r:r*caution,  
  	R:2^r,
  	/* */
  	w:float(rectform(ev(R*exp(2*%pi*%i*t)))),
  	/* */
  	last_z:z,
  	z:Psi_n(r,t,last_z,R_max), /* z=Psi_n(w) */
  	dz : cabs ( z - last_z),
  	zz:cons(z,zz)
  ),
  return(zz)
 )$





  


/* 
converts complex number z = x*y*%i 
to the list in a draw format:  
[x,y] 
*/
d(z):=[float(realpart(z)), float(imagpart(z))]$

ToPoints(myList):= points(map(d,myList))$


/* give Draw List from one point*/
ToPoint(z):=points([d(z)])$






 /*  compile(all)$  */

 /* ----------------------- main ----------------------------------------------------*/


start:elapsed_run_time ();
  
 HitLimit:15$ /* proportional to number of details and time of drawing */
 /* external angle in turns */
 /* resolution is proportional to number of details and time of drawing */
 iX_max:2000$
 iY_max:2000$
 /* define z-plane ( dynamical ) */
 ZxMin:-2.0$
 ZxMax:2.0$
 ZyMin:-2.0$
 ZyMax:2.0$

  t:129/16256$

/* give c a value */
 c: 0.397391822296541  +0.133511204871878*%i  $ /*  one can compute it from t  */


 /* compute fixed points */
 Beta:float(rectform((1+sqrt(1-4*c))/2)); /* compute repelling fixed point beta */
 alfa:float(rectform((1-sqrt(1-4*c))/2)); /* other fixed point */


 /* compute backward orbit of repelling fixed point*/
 xy: GiveBackwardOrbit(c,Beta,ZxMin,ZxMax,ZyMin,ZyMax,iX_max,iY_max, HitLimit)$ 
 

  /* compute ray points & save to zz list  */  
 eRay : GiveRay(t,c)$
 
 eRayT:GiveRay(t/2,c)$
 eRayTp:GiveRay((t+1)/2,c)$
 



 /* time of computations */
 time:fix(elapsed_run_time ()-start);

 /* draw it using draw package by */
 
 
 
 load(draw)$ 

 path:"~/maxima/batch/julia/knead/k_129_16256/"$ /*  if empty then file is in a home dir */

 /* if graphic  file is empty (= 0 bytes) then run draw2d command again */
 
 draw2d(
  terminal  = 'svg,
  file_name = sconcat(path,"2_",string(HitLimit)),
  user_preamble="set size square;set key top right",
  title= concat("Dynamical plane for fc(z)=z*z+",string(c)),
  dimensions = [iX_max, iY_max],
  yrange = [ZyMin,ZyMax],
  xrange = [ZxMin,ZyMax],
  xlabel     = "Z.re ",
  ylabel     = "Z.im",
  point_type = filled_circle,
  points_joined =true,
  point_size    =  0.2,
  color         = red,
    
   
  
  points_joined =false,
  color         = black,
  key = "backward orbit of z=beta",
  points(map(realpart,xy),map(imagpart,xy)),
  
  
  
  points_joined =false,
  color         = green,
  point_size    =  1.4,
  key = "critical value",
  ToPoint(c),
  
  
  key = sconcat("external ray t=",string(t)),
  color = green,
  points_joined =true,
  point_size    =  0.2,
  ToPoints(eRay),
  
  
 
  points_joined = false,
  color         = black,
  point_size    =  1.4,
  key = "critical point z = 0.0",
  ToPoint(0.0),

  points_joined =true,
  point_size    =  0.2,
  color         = red,
  key = sconcat("external ray t/2 = ", string(t/2)),
  ToPoints(eRayT),
  
  
  key =  sconcat("external ray (t+1)/2 =",string((t+1)/2)),
  color = magenta,
  ToPoints(eRayTp)
 
  
  
 )$

1. ↑ Rational External Rays of the Mandelbrot Set by Dierk Schleicher
2. ↑ Hausdorff dimension of biaccessible angles of quadratic Julia sets and of the Mandelbrot set by Henk Bruin joint work with Dierk Schleicher