Datei:H2OrbitalsAnimation.gif
Es ist keine höhere Auflösung vorhanden.
H2OrbitalsAnimation.gif (300 × 204 Pixel, Dateigröße: 411 KB, MIME-Typ: image/gif, Endlosschleife, 91 Bilder)
Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Wikimedia Commons eingebunden.
Beschreibung
| Beschreibung |
English: Electron wavefunctions for the 1s orbital of the hydrogen atom (left and right) and the corresponding bonding (bottom) and antibonding (top) orbitals of the dihydrogen molecule. The real part of the wavefunction is the blue curve, the imaginary part is the red curve. The red dots mark the locations of the protons. The electron wavefunction oscillates according to the Schrödinger equation, and the orbitals are standing waves. The standing wave frequency is proportional to the energy of the orbital. Hydrogen is really a 3D system, but this is a 1D slice. These are schematic plots: I did not bother to solve the Schrödinger equation quantitatively. The plots are arranged like a molecular orbital diagram. |
| Datum | |
| Quelle | Eigenes Werk |
| Urheber | Sbyrnes321 |
(*Source code written in Mathematica 6.0 by Steve Byrnes, March 2011. This source code is public domain.*)
(*Shows schematic electron wavefunctions for 1s orbital of hydrogen atom, and 1s bonding and
antibonding orbitals of hydrogen molecule. Plotted as a 1D slice of a 3D system.
All graphs are schematic: I'm not actually solving the Schrodinger equation, but hopefully it looks like I did. *)
ClearAll["Global`*"]
(***Oscillation frequencies, in units of oscillations per cycle of the animated gif***)
sfreq = 4;
bondfreq = 3;
antibondfreq = 5;
(***Wavefunction normalization coefficients***)
scoef = 0.893;
bondcoef = 0.618;
antibondcoef = 0.646;
(***Define wavefunctions***)
s[x_, t_] := scoef * Exp[-(x - 1.25)^2]*Exp[-2*Pi*I*sfreq*t];
bond[x_, t_] := bondcoef * (Exp[-x^2] + Exp[-(x - 2.5)^2]) * Exp[-2*Pi*I*bondfreq*t];
antibond[x_, t_] := antibondcoef * (Exp[-x^2] - Exp[-(x - 2.5)^2]) * Exp[-2*Pi*I*antibondfreq*t];
(***Make individual graphs***)
SetOptions[Plot, {Ticks -> None, PlotStyle -> {Directive[Thick, Blue], Directive[Thick, Pink]},
Axes -> {True, False}, PlotRange -> {{-2.5, 5}, {-1, 1}},
AspectRatio -> 1.1}, Frame -> True, FrameTicks -> None];
SetOptions[ListPlot, {Ticks -> None, PlotStyle -> Directive[Red, AbsolutePointSize[10]]}, Axes -> {True, False}];
OneProton = ListPlot[{{1.25, 0}}];
TwoProtons = ListPlot[{{0, 0}, {2.5, 0}}];
SWaves[t_] := Plot[{Re[s[x, t]], Im[s[x, t]]}, {x, -2.5, 5}];
BondWaves[t_] := Plot[{Re[bond[x, t]], Im[bond[x, t]]}, {x, -2.5, 5}];
AntibondWaves[t_] := Plot[{Re[antibond[x, t]], Im[antibond[x, t]]}, {x, -2.5, 5}];
SPlot[t_] := Show[SWaves[t], OneProton];
BondPlot[t_] := Show[BondWaves[t], TwoProtons];
AntibondPlot[t_] := Show[AntibondWaves[t], TwoProtons];
(***Draw all graphs together, arranged in the shape of a molecular orbital diagram***)
TotalPlot[t_] :=
Graphics[{White, Rectangle[{0, 0}, {1.5, 1}],
Inset[SPlot[t], ImageScaled[{0, 0.5}], ImageScaled[{0, 0.5}], .45],
Inset[SPlot[t], ImageScaled[{1, 0.5}], ImageScaled[{1, 0.5}], .45],
Inset[BondPlot[t], ImageScaled[{0.5, 0}], ImageScaled[{0.5, 0}], .45],
Inset[AntibondPlot[t], ImageScaled[{0.5, 1}], ImageScaled[{0.5, 1}], .45]}, ImageSize -> 300]
(***Export animation***)
output = Table[TotalPlot[t], {t, 0, 90/91, 1/91}];
SetDirectory["C:\\Users\\Steve\\Desktop"]
Export["test.gif", output]
Lizenz
Ich, der Urheber dieses Werkes, veröffentliche es unter der folgenden Lizenz:
 
|
Diese Datei wird unter der Creative-Commons-Lizenz CC0 1.0 Verzicht auf das Copyright zur Verfügung gestellt. |
| Die Person, die das Werk mit diesem Dokument verbunden hat, übergibt dieses weltweit der Gemeinfreiheit, indem sie alle Urheberrechte und damit verbundenen weiteren Rechte – im Rahmen der jeweils geltenden gesetzlichen Bestimmungen – aufgibt. Das Werk kann – selbst für kommerzielle Zwecke – kopiert, modifiziert und weiterverteilt werden, ohne hierfür um Erlaubnis bitten zu müssen.
|
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
| Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
|---|---|---|---|---|---|
| aktuell | 09:35, 28. Mär. 2011 | | 300 × 204 (411 KB) | Sbyrnes321 | Fixed the sign of the complex phase oscillation |
| 09:28, 28. Mär. 2011 |  | 300 × 204 (411 KB) | Sbyrnes321 | {{Information |Description ={{en|1=Electron wavefunctions for the 1s orbital of the hydrogen atom (left and right) and the corresponding bonding (bottom) and antibonding (top) orbitals of the dihydrogen molecule. The real part of the wavefunction is th |
Dateiverwendung
Keine Seiten verwenden diese Datei.
Globale Dateiverwendung
Die nachfolgenden anderen Wikis verwenden diese Datei:
- Verwendung auf bs.wikipedia.org
- Verwendung auf el.wikipedia.org
- Verwendung auf en.wikipedia.org
- Verwendung auf en.wikiquote.org
- Verwendung auf ja.wikipedia.org
- Verwendung auf pt.wikipedia.org
- Verwendung auf simple.wikipedia.org
- Verwendung auf sr.wikipedia.org
